تبلیغات
آموزش نرم افزار های تخصصی - یافتن اعداد جا افتاده در سری اعداد متوالی در اکسل

یافتن اعداد جامانده از سری

فرض کنید دریک ستون از اکسل شماره ردیفی ایجاد نموده و اعداد را بطور متوالی در آن درج نموده اید حال اگر در این توالی یک یا چند عدد از قلم بیفتد و یا بعدها یک یا چند عدد را از این توالی حذف نمایید یافتن اینکه چه اعدادی در این سری جا افتاده و یا حذف شده اند درصورتی که تعداد این ردیف اعداد زیاد باشد کار وقت گیر و مشکلی خواهد بود . 
اما در این مطلب فرا خواهیم گرفت که چگونه این اعداد را به راحتی پیدا نموده و از آنها استفاده نماییم 
در ادامه مطلب همراه من باشید . 
 صفحه کاری اکسل خود را باز نمایید و درون ستون اول یک سری از اعداد متوالی را درج نمایید . ستون دیگری را نیز برای یافتن و نمایش اعداد جامانده در نظر بگیرید

تصویراول

2. با فشردن همزمان کلیدهای  ALT+F11 وارد محیط کد نویسی شده و کدهای  زیر را در این محیط کپی نمایید
Option Explicit

Sub FindMissingvalues()
   
    Dim InputRange As Range, OutputRange As Range, ValueFound As Range
    Dim LowerVal As Double, UpperVal As Double, count_i As Double, count_j As Double
    Dim NumRows As Long, NumColumns As Long
    Dim Horizontal As Boolean
   

    Horizontal = False
       
    On Error GoTo ErrorHandler
   
  
    Set InputRange = Application.InputBox(Prompt:="سری اعداد مورد نظر خود را انتخاب نمایید  :", _
        Title:="یافتن اعداد جا مانده", _
        Default:=Selection.Address, Type:=8)
   
       
  
    LowerVal = WorksheetFunction.Min(InputRange)
    UpperVal = WorksheetFunction.Max(InputRange)
   
       

    Set OutputRange = Application.InputBox(Prompt:="محل نمایش نتایج را مشخص کنید :", _
        Title:="انتخاب مقصد ", _
        Default:=Selection.Address, Type:=8)

    NumRows = OutputRange.Rows.Count
    NumColumns = OutputRange.Columns.Count
   
   
    If NumRows < NumColumns Then
   
        Horizontal = True
    
        NumRows = 1
       
    Else
   

        NumColumns = 1
       
    End If
   

    count_j = 1
    For count_i = LowerVal To UpperVal
   

        Set ValueFound = InputRange.Find(count_i, LookIn:=xlValues, LookAt:=xlWhole)

        If ValueFound Is Nothing Then
       
            If Horizontal Then
           
                OutputRange.Cells(NumRows, count_j).Value = count_i
                count_j = count_j + 1
           
            Else
               
                OutputRange.Cells(count_j, NumColumns).Value = count_i
                count_j = count_j + 1
           
            End If
           
        End If
       
    Next count_i
   
    Exit Sub
   
ErrorHandler:

    If InputRange Is Nothing Then
   
        MsgBox "خطای کاربر  : سلول های مبدا تعیین نشده اند ."
        Exit Sub
       
    End If
   
    If OutputRange Is Nothing Then
   
        MsgBox "خطای کاربر :سلول های مقصد تعیین نشده اند ."
        Exit Sub
       
    End If
   
    MsgBox "An error has occurred. The macro will end."
   

End Sub


3. اکنون از سربرگ Developer  و از گزینه Insert یک Command Bottumn  را به محیط اکسل اضافه نمایید و با کلیک بر روی آن عنوان آن را به "یافتن اعداد جامانده " تغییردهید .

تصویر-2

4. به محض قرار دادن
Command Bottumn یک پنجره بصورت خودکار باز شده تا بتوانید منبع کدهای مرتبط با این دکمه را برای آن مشخص نمایید . در اینجا کدهای ماکرو که به نام findmissingvalue  می باشد را انتخابنموده و در انتها OK  را فشار دهید .

یافتن اعداد


5. حال بر روی دکمه ای که ایجاد نمویدید کلیک نموده و طبق پنجره های راهنما عمل نمایید تا نتیجه حاصل گردد .


خواندن این مطالب را هم به شما پیشنهاد می کنم :








طبقه بندی: آموزش EXCEL،
برچسب ها:سری اعداد، اکسل، اعداد جامانده، ماکرو،
تاریخ : دوشنبه 25 دی 1396 | 08:21 ق.ظ | نویسنده : امید شهری | نظرات()
.: Weblog Themes By Bia2skin :.